Các cách thêm dòng mới vô 1 CSDL (cơ sở dữ liệu) đã sẵn

minhtiep178

New Member
Hội viên mới
Ðề: Bạn xài macro này xem có thuận tiện hơn không:

(*) Bạn chưa nói là đã giảm đi từ 2 giờ xuống còn bao nhiêu giờ?
:D Chắc bây giờ còn khoảng 30'

(*) Bạn nên nói trước rằng, hiện đang ngụ nơi mô?!, Mình đến cầu Ng. Tri Fương thì gần!
Vậy bác ở tận Sài Gòn ah? Xa quá, e ở Hải Dương
Chúc cuối tuần vui vẻ!:kingkong:
Cám ơn bác nhé
 

TQChanh

Member
Hội viên mới
Ðề: Thêm hay xóa số dòng giống nhau ở 5 trang tính cùng lúc

Nội dung macro như sau:

PHP:
Option Explicit
Sub gpeThemXoaDong()
 Dim AddDel As String, ShName As String
 Dim DongDau As Long, SoDong As Byte, J As Byte
 
 Sheets("MaU").Select
 AddDel = InputBox("Them : 'T'" & Chr(10) & "Xóa: 'X'", "Hay Nhap Chu Cái Thích Hop:", "T")
 AddDel = UCase$(AddDel)
 DongDau = InputBox("Hay Nhap Dòng Dàu De Xu Lý:")
 SoDong = InputBox("Nhap Só Dòng Càn Xu Lý:") - 1
 For J = 1 To 5
    ShName = Choose(J, "T01", "T02", "T03", "THop", "Form", "GPE")
    With Sheets(ShName).Rows(DongDau & ":" & DongDau + SoDong)
        If AddDel = "T" Then
            .Insert Shift:=xlDown
        ElseIf AddDel = "X" Then
            .Delete
        Else
            MsgBox "GPE.COM Xin Chào Ban!"
        End If
    End With
 Next J
End Sub
Chúc nghĩ lễ vui vẻ!:cuoiranuocmat:
 

minhtiep178

New Member
Hội viên mới
Ðề: Thêm hay xóa số dòng giống nhau ở 5 trang tính cùng lúc

Nội dung macro như sau:

PHP:
Option Explicit
Sub gpeThemXoaDong()
 Dim AddDel As String, ShName As String
 Dim DongDau As Long, SoDong As Byte, J As Byte
 
 Sheets("MaU").Select
 AddDel = InputBox("Them : 'T'" & Chr(10) & "Xóa: 'X'", "Hay Nhap Chu Cái Thích Hop:", "T")
 AddDel = UCase$(AddDel)
 DongDau = InputBox("Hay Nhap Dòng Dàu De Xu Lý:")
 SoDong = InputBox("Nhap Só Dòng Càn Xu Lý:") - 1
 For J = 1 To 5
    ShName = Choose(J, "T01", "T02", "T03", "THop", "Form", "GPE")
    With Sheets(ShName).Rows(DongDau & ":" & DongDau + SoDong)
        If AddDel = "T" Then
            .Insert Shift:=xlDown
        ElseIf AddDel = "X" Then
            .Delete
        Else
            MsgBox "GPE.COM Xin Chào Ban!"
        End If
    End With
 Next J
End Sub
Chúc nghĩ lễ vui vẻ!:cuoiranuocmat:
Bác TQchanh ơi e chạy code nó báo lỗi ở dòng 11. mà Bác có biết về VBA của Cad không? E sưu tầm dc doạn code VBA của cad nhưng khi chạy ko đc theo ý mình nhờ bác sửa giúp
Chúc bác nghỉ lế vui vẻ
 

Đính kèm

Sửa lần cuối:

congson19

New Member
Hội viên mới
nhờ các bác giúp vấn đề này

em không rành về excel lắm nên nhờ các đàn anh giúp em chỗ này với ạ!
yêu cầu như sau: mỗi khi ô A1 thay đổi dữ liệu thì tự động cập nhập vào cột B:B từ trên xuống dưới
mong các bác giúp em !
 

TQChanh

Member
Hội viên mới
Ðề: Thêm hay xóa số dòng giống nhau ở 5 trang tính cùng lúc

(1)Bác TQchanh ơi e chạy code nó báo lỗi ở dòng 11.
(2) Mà Bác có biết về VBA của Cad không? E sưu tầm dc doạn code VBA của cad nhưng khi chạy ko đc theo ý mình nhờ bác sửa giúp
Chúc bác nghỉ lế vui vẻ
(1) Dòng 11 là dòng nào vậy, sao bạn không trích dẫn ra luôn dùm đi?!

(2) VBA trong OTOCad chắc bạn qua GPE.COM hỏi coi sao;
Ở đó Thầy Hướng vững nhiều về thứ này!

Chúc vui nhân ngày 1/5
 

TQChanh

Member
Hội viên mới
Ðề: Thêm số dòng đã định vô những vị trị chỉ định

Các bạn nghiên cứu macro này xem nó thêm dòng theo kiểu gì?!
:giavo:
PHP:
Option Explicit
Sub ThemDong()
 Dim Nn As Long, Kk As Long, J As Long
 Const aA As Integer = 2:               Const Bb As Integer = 1
 On Error Resume Next
 Kk = InputBox("Hãy Nhap Só Hàng Càn Them:", "GPE.COM Xin Chào", 2)
 Nn = InputBox("Hãy Nhap Giá Tri Cuc Dai Cua N:", "GPE.COM", 3)
 For J = Nn To 1 Step -1
    Cells(aA * (J) ^ 2 - Bb, 1).Interior.ColorIndex = 34 + (J Mod 9)
    Cells(aA * (J) ^ 2 - Bb, 1).Resize(Kk).EntireRow.Insert
 Next J
End Sub
Tham khảo thêm tại: Thm k c?t(hng) vo cc c?t(hng) ??nh tr??c
 

TQChanh

Member
Hội viên mới
Ðề: Thêm dòng với nội dung tăng dần fù hợp trình tự định trước.

Dưới đây là bảng liệt kê các trận thi đấu tranh giải khác nhau của 1 đơn vị hành chính:

PHP:
TT|'Vòng TĐ'|Độ tuổi   |Hạng|Đ. |Loại |'Số đội'|..
1 |Chung kết|Nhi       |E1  |R  |Latin|  7     |..
2 |Tứ kết   |Nhi       |F1  |R  |Latin|  15    |..
3 |Bán kết  |Thiếu niên|D   |C,R|Latin|  12    |..
4 |Chung kết|Nhi       |E2  |C,R|Latin|  3     |..
5 |Vòng loại|Thiếu Nhi |F1  |R  |Latin|  27    |..
6 |Chung kết|Nhi đồng1 |E3  |R,J|Latin|  7     |..

Nhiệm vụ đề ra là ta fải tiến hành thêm 1 dòng bên dưới các dòng mà cột có tên 'Vòng đấu' không chứa từ 'Chung kết'
Hơn nửa tại cột này & cột số đội ở dòng mới sẽ thay theo qui luật sau:
(*) [Cột vòng TĐ] thay theo trình tự 'Vòng loại' => 'Tứ kết' => 'Bán kết' => 'Chung kết'
(*) [Cột Số đội] theo trật tự sau: (Hơn 24) => 24 => 12 => 6
Còn các cột khác của dòng mới này lấy số liệu của dòng trên nó.

Các bạn xem file có tại bài 5 ở đây: Ch�n th�m d�ng c� ?i?u ki?n

:thadieu:
 

hung2412

New Member
Hội viên mới
Ðề: Điền đầy bằng các dòng trống vô 1 CSDL sẵn có số thứ tự không liên tục

BÀI II THÊM DÒNG MỚI ĐỂ CÓ TRẬT TỰ CHO TRƯỚC

Ví dụ ta có CSDL như sau:
Mã:
[B]STT  HTen    Phái   NgSinh[/b]
3   Hà My     Nam    4/1/75
5   Hà Vy     Nữ     1/4/75
' . . . . . . . . '
Giờ ta muốn thêm 2 dòng trống trên chàng Hà My & 1 dòng trên nàng Hà Vy, để trở thành như sau:

Mã:
1
2
3   Hà My     Nam    4/1/75
4
5   Hà Vy     Nữ     1/4/75
' . . . . . . . . '
(Có nghĩa là: Thêm 2 dòng cho chàng Hà My ( số 3) & 1 dòng cho nàng Hà Vy (số 5))

Chuyện như vậy sẽ nhanh chóng & không khó, một khi ta có trong tay macro như sau

Mã:
Option Explicit
[B]Sub ThemCacDongTrong()[/B]
 Dim Rng As Range, sRng As Range
 Dim Max_ As Long, jJ As Long
 
 Sheets("GPE1").Select:                         Columns("A:J").Delete
 ThisWorkbook.Worksheets("S0").[B2].CurrentRegion.Copy Destination:=[A1]
 
 Set Rng = Range([A2], [A65500].End(xlUp))
 Max_ = Application.WorksheetFunction.Max(Rng)
 For jJ = 1 To Max_
    Set sRng = Rng.Find(jJ, , xlFormulas, xlWhole)
    If sRng Is Nothing Then
        [A65500].End(xlUp).Offset(1).Value = jJ
    End If
 Next jJ
 Set Rng = [B2].CurrentRegion.Offset(1)
 Rng.Sort Key1:=Range("A3"), Order1:=xlAscending, Header:=xlGuess, _
    OrderCustom:=1, Orientation:=xlTopToBottom
 Randomize:             [A1].Interior.ColorIndex = 34 + 9 * Rnd() \ 1
[B]End Sub[/B]
Ghi chú theo macro ta có: CSDL nguồn tại trang tính 'S0';
Kết quả mà macro đem lại tại trang tính có tên 'GPE1'
Bạn ơi, mình làm theo thì excel hiện ra bảng thông báo "subscript out of range" là sao nhỉ? Khắc phục như thế nào vậy bạn?
 

TQChanh

Member
Hội viên mới
Ðề: Điền đầy bằng các dòng trống vô 1 CSDL sẵn có số thứ tự không liên tục

Bạn ơi, mình làm theo thì excel hiện ra bảng thông báo "subscript out of range" là sao nhỉ? Khắc phục như thế nào vậy bạn?
Bạn đưa file mà chạy macro báo lỗi lên đi; Mình & các bạn khác sẽ xem & trợ giúp thêm, nếu được.
 

TQChanh

Member
Hội viên mới
Ðề: Thêm 5 dòng vô mỗi 1 dòng

Mình có bảng dữ liệu như vùng được tô màu vàng như trong file đ1nh kèm

Giờ mình muốn mỗi hàng tương ứng ở cột [A] được thêm 5 dòng nữa với yêu cầu sau:

(*) Ở cột [A]: Giá trị cả 5 dòng thêm trùng với dòng đang khảo sát;

(*) Các cột & [C] lấy giá trị của vùng [B4:C8]

Macro để thực hiện nhiệm vụ có nội dung như sau:

PHP:
Option Explicit
Sub Them5Dong()
 Dim Cls As Range
 Dim Rws As Long, J As Long, W As Long, Dg As Long
    
 Sheets("Nguon").Select
 Rws = [A3].End(xlDown).Row
 Dg = [B3].End(xlDown).Row
 ReDim Arr(1 To Rws * Dg, 1 To 3)
 For J = 4 To Rws
    For Each Cls In Range([B4], [B4].End(xlDown))
        W = W + 1
        Arr(J - 4 + W, 1) = Cells(J, "A").Value
        Arr(J - 4 + W, 2) = Cls.Value
        Arr(J - 4 + W, 3) = Cls.Offset(, 1).Value
    Next Cls
    W = W - 1
 Next J
 [A4].Resize(Dg * Rws, 3).Value = Arr()
End Sub
 

Đính kèm

TQChanh

Member
Hội viên mới
Nhờ Quý vị và các bạn giúp đỡ cho tôi vấn đề cụ thể như sau:
Tự động thêm dòng đầu tiên (Và tô màu cho dòng thêm đó) cho nhóm ký tự giống nhau của các ô ở cột B (Các ký tự đầu giống nhau có thể từ 2 => 4 ký tự và không bao gồm ký tự là số)
(Kiểu như là thêm dòng tiêu đề cho các nhóm ký tự giống nhau).
(ác bạn sẽ rõ hơn khi xem tại:
http://www.giaiphapexcel.com/forum/showthread.php?97411-Cần-giúp-đỡ-tự-động-thêm-dòng-(Và-tô-màu-vàng-cho-dòng-thêm-đó)-dựa-trên-ký-tự-của-ô
 

thanhkt79

New Member
Hội viên mới
Em chào anh TQChanh
VBA code a viết tuyệt quá. Em rất thích nhưng loay hoay mãi vẫn mông lung quá
A giúp e với.
em có file kiểu như này:
Bước 1: đếm số dòng ở cột A có chứa dữ liệu ở Sheet "1311"
Bước 2 lại đếm số dòng từ
ACCOUNT AND NOTES RECEIVABLE đến END ACCOUNT AND NOTES RECEIVABLE ở cột E chứa số >0 ở sheet "Jan"
Bước 3: So sánh số dòng đếm được ở bước 1 và bước 2
- Nếu số dòng bước 1< bước 2 thì chèn thêm dòng đúng bằng số dòng chênh lệch ( dạng insert copy cell)
- Ngược lại: xóa bớt dòng
Bước 4: copy dữ liệu từ ô A10 đến ô A64 ở sheet "1311" vào ô A3 đến A20 ở sheet "Jan"
copy dữ liệu từ ô E10 đến ô E64 ở sheet "1311" vào ô E3 đến E20 ở sheet "Jan"
rồi lại làm tương tự với vùng
Accrued cost of projects ở sheet "Jan" với sheet "33505"
 

Đính kèm

TQChanh

Member
Hội viên mới
Chèn thêm hàng có điều kiện và tự đông tính tổng

Chào Anh/ Chị
Mình có File excel nhập theo số công đoạn của chuyền may và số lượng từng công đoạn,
Có cách nào tự động chèn một hàng sau mỗi công đoạn và tự động tính tổng sản lượng của mỗi công đoạn.
Xin cám ơn.
PHP:
Option Explicit
Sub ChenHangVaTinhTong()
 Dim Arr(), CSDL(), Dic As Object
 Dim Tong As Double, J As Long, W As Long
 Dim StrC As String
 Sheets("DuLieu").Select
 Set Dic = CreateObject("Scripting.Dictionary")
 CSDL() = [B2].CurrentRegion.Offset(1).Value
 ReDim Arr(1 To 99 + UBound(CSDL, 1), 1 To 4)
 For J = 1 To UBound(CSDL(), 1)
  StrC = "L" & CStr(CSDL(J, 3))
  If Not Dic.exists(StrC) Then
  W = W + 2
  Dic.Add StrC, W
  Arr(W, 1) = CSDL(J, 1):  Arr(W, 2) = CSDL(J, 2)
  Arr(W, 3) = CSDL(J, 3):  Arr(W, 4) = CSDL(J, 4)
  Arr(W - 1, 4) = Tong:  Tong = Arr(W, 4)
  Else
  W = W + 1
  Arr(W, 1) = CSDL(J, 1):  Arr(W, 2) = CSDL(J, 2)
  Arr(W, 3) = CSDL(J, 3):  Arr(W, 4) = CSDL(J, 4)
  Tong = Tong + Arr(W, 4)
  End If
 Next J
 [f2].Resize(W + 9, 4).Value = Arr()  '!!!'
End Sub
(http://www.giaiphapexcel.com/forum/showthread.php?102596-Ch%C3%A8n-th%C3%AAm-h%C3%A0ng-c%C3%B3-%C4%91i%E1%BB%81u-ki%E1%BB%87n-v%C3%A0-t%E1%BB%B1-%C4%91%C3%B4ng-t%C3%ADnh-t%E1%BB%95ng)
 

TQChanh

Member
Hội viên mới
Jindo có file cần chèn thêm 3 dòng & lặp lại đòng tiêu đề sau mỗi Inv-No mới. Nhưng trong file đó cũng có 1 Inv-No chỉ có 1 dòng, nhưng cũng có có thể có 1 Lot-No trùng nhiều dòng. ACE giúp dùm với vì dữ liệu rất lớn nên không thể ngồi insert nhiều lần và động tác này lập đi lập lại. ACE giúp với.
Các bạn có thể xem hình tại #8 ở: http://www.giaiphapexcel.com/forum/showthread.php?103404-Code-insert-them-3-dong&p=643104#post643104
Macro có nội dung như sau:
PHP:
Option Explicit
 Dim Ar0(), Arr(), dArr()
Sub Them3Dong()
 Dim Rws As Long, J As Long, W As Long
 ReDim Ar0(1 To 1, 1 To 7)
 Rws = [B1].CurrentRegion.Rows.Count
 Ar0() = [A1:G1].Value
 Arr() = [A2].Resize(Rws + 1, 7).Value
 ReDim dArr(1 To 4 * Rws, 1 To 7)
  W = 1:  TDe W
 For J = 1 To UBound(Arr())
  W = W + 1:  dArr(W, 3) = Arr(J, 3)
  dArr(W, 1) = Arr(J, 1):  dArr(W, 2) = Arr(J, 2)
  If Arr(J + 1, 1) <> Arr(J, 1) And Arr(J + 1, 1) <> "" Then
  W = W + 4:  TDe W
  ElseIf Arr(J + 1, 1) = Arr(J, 1) Then
  dArr(W, 1) = Arr(J, 1):  dArr(W, 2) = Arr(J, 2)
  dArr(W, 3) = Arr(J, 3)
  End If
  If Arr(J + 1, 1) = "" Then Exit For
 Next J
 [r1].Resize(9 + W, 7).Value = dArr()
End Sub
Mã:
Sub TDe(Rw As Long)
 Dim J As Byte
 For J = 1 To 7
  dArr(Rw, J) = Ar0(1, J)
 Next J
End Sub
 

TQChanh

Member
Hội viên mới
Mình có bảng số liệu trên trang tính 'MaSo' bắt đầu từ [B4] như mô fỏng dưới đây:
PHP:
Mã | Danh Sách Tiêu chuẩn
  1   |TCVN 55:2014
      |TCVN 53:2015
   2  |TCVN 2010:10
      |TCVN 3000-00
      |TCVN 1986-13
   3  |TCVN 60:2015
      |TCVN 74:2014
      |TCVN 79:2015
      |TCVN 4065-88
. . . . . . .
Có nghĩa là ứng với 1 mã tiêu chuẩn ta c0o1 thể có các tiêu chuẩn khác nhau về số lượng, có thể từ 1 đến 7 tiêu chuẩn;
Công việc của mình fải làm là:
Ở trang tính khác ta cần chọ 1 trong các mã ở ô [P2] thì tại cột [B:B] bắt đầu từ [B7] hiện lên tất tần tật các tiêu chuẩn ứng với nó, & buột fải có 2 dòng tên chúng & 1 dòng dưới chúng có nội dung như dau:
PHP:
'a. Tiêu Chuẩn'
- Các tiêu chuẩn về điều hòa không khí và thông gió:
TCVN 60:2015
TCVN 74:2014
TCVN 79:2015
TCVN 4065-88
'b.Các catalogue thiết bị'
+ Máy và thiết bị lạnh : FUJITSU, CARRIER, DAIKIN, TRANE
Như đã nêu ở trên, số lượng các tiêu chuẩn ứng với từng mã là khác nhau, nên có lúc ta cần xóa bớ dòng & cũng fải có lúc ta cần thêm dòng để liệt kê các tiêu chuẩn của mã giữa các dòng buột có của Form;

Macro sau sẽ làm được việc đó:
PHP:
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Sh As Worksheet, Rng As Range, sRng As Range, Rg0 As Range, Cls As Range
Dim DgCu As Long, DgMoi As Long, J As Integer
If Not Intersect(Target, [P2]) Is Nothing Then
  DgCu = [C8].Resize(13).Find("b.", , xlFormulas, xlPart).Row - 9
  Set Sh = ThisWorkbook.Worksheets("Ma so")
  Sh.[C65500].End(xlUp).Offset(1, -1).Value = "GPE.COM"
  Set Rng = Sh.Range(Sh.[B4], Sh.[b65500].End(xlUp))
  Set sRng = Rng.Find(Target.Value, , , xlWhole)
  If sRng Is Nothing Then
  MsgBox "Nothing"
  Else
  Set Rg0 = Sh.Range(sRng.Offset(, 1), sRng.End(xlDown).Offset(-1, 1))
  DgMoi = Rg0.Rows.Count
  If DgMoi < DgCu Then
  [C10].Resize(DgCu - DgMoi).EntireRow.Delete
  ElseIf DgMoi > DgCu Then
  [C10].Resize(DgMoi - DgCu).EntireRow.Insert
  End If
  For Each Cls In Rg0
  J = J + 1
  [C8].Offset(J).Value = Cls.Value
  Next Cls
  End If
  Randomize:  Target.Interior.ColorIndex = 34 + 9 * Rnd() \ 1
End If
End Sub
Các bạn có thể tham khảo tại: http://www.giaiphapexcel.com/forum/showthread.php?103697-Nhờ-cao-thủ-viết-code-tự-chèn-thêm-hoặc-bớt-dòng-trong-excel
 

TQChanh

Member
Hội viên mới

Đính kèm

TQChanh

Member
Hội viên mới
TRong hình ta có 2 bảng dữ liệu; Bảng bên trái là dữ liệu gốc;
Giờ tác giả muốn thêm số dòng ứng với số nhóm của cột [G] (phòng thi)
Giả dụ tại [G5] ta có 'C103/C203/D034' thì cần thêm 3 dòng,. . . để đạt được kết quả như bảng dữ liệu bên fải
Sau đây là macro làm nên điều đó:
PHP:
Option Explicit
Sub ThemDongDL()
 Dim Rws As Long, J As Long, W As Long, Dm As Byte, VTr As Byte
 Dim Tmp$, CuThe As String:  Dim Arr()
 Const FC As String = "/"
 
 Sheets("Du Lieu").Select
 Rws = [b2].CurrentRegion.Rows.Count
 ReDim dArr(1 To 9 * Rws, 1 To 10)
 Arr() = [b2].Resize(Rws, 10).Value
 For J = 1 To UBound(Arr())
  If Arr(J, 6) = "" Then Exit For
  If InStr(Arr(J, 6), FC) Then
  Tmp = Arr(J, 6) & FC
  Do
  VTr = InStr(1, Tmp, FC)
  If VTr < 1 Then Exit Do
  CuThe = Left(Tmp, VTr - 1)
  W = W + 1:  dArr(W, 1) = W
  For Dm = 2 To 10
  If Dm <> 8 Then
  dArr(W, Dm) = Arr(J, Dm - 1)
  Else
  dArr(W, 8) = CuThe
  End If
  Next Dm
  Tmp = Mid(Tmp, VTr + 1, Len(Tmp))
  Loop
  Else
  W = W + 1:  dArr(W, 1) = W
  For Dm = 2 To 10
  If Dm <> 8 Then
  dArr(W, Dm) = Arr(J, Dm - 1)
  Else
  dArr(W, 8) = Arr(J, 6) & "."
  End If
  Next Dm
  End If
 Next J
 [L2].Resize(W, 10).Value = dArr()
End Sub
 

Đính kèm

TQChanh

Member
Hội viên mới
Giả dụ mình có 1 bảng dữ liệu (gồm nhiều hàng & 15 cột) như sau:
PHP:
AA    BxB . . .   11; 132; 963
BC    YxY . . .   14; 201; 121
Giờ mình muốn chuyển bảng dữ liệu này thành nhiều dòng có dạng như sau:
Mã:
AA  BxB . . .  11
AA  BxB . . .  132
AA  BxB . . .  963
BC  YxY  . . . 14
BC  YxY  . . . 201
BC  YxY  . . . 121
Macro sau đây sẽ giúp mình làm việc đó
PHP:
Option Explicit
Sub TachDong()
Dim sArr:  Dim xArr
Dim I As Long, J As Long, W, Z, F As Long
With Sheet1
  J = .[A2].CurrentRegion.Rows.Count
  sArr = .Range(.[A2], .[A65000].End(xlUp)).Resize(, 15)
End With
ReDim Darr(1 To 9 * J, 1 To 15)
On Error Resume Next
For I = 1 To UBound(sArr)
  xArr = Split(sArr(I, 15), ";")
  For Z = 0 To UBound(xArr)
  W = W + 1
  Darr(W, 1) = W
  Darr(W, 15) = xArr(Z)
  For F = 2 To 14
  Darr(W, F) = sArr(I, F)
  Next F
  Next Z
Next I
With Sheet2
  .[A2:O50000].ClearContents
  If W Then
  .[A2].Resize(W, 15).Value = Darr
  J = .[A65000].End(3).Row
  .[A2:O65000].Borders.LineStyle = 0
  .Range("A2:O" & J).Borders.LineStyle = 1
  Else
  .[A2:O65000].Borders.LineStyle = 0
  .[A2:O65000].ClearContents
  End If
End With
End Sub
(http://www.giaiphapexcel.com/forum/showthread.php?109066-Tách-dữ-liệu-thành-nhiều-dòng)
 

nmt002

New Member
Hội viên mới

CẨM NANG KẾ TOÁN TRƯỞNG


Liên hệ: 090.6969.247

KÊNH YOUTUBE DKT

Kỹ thuật giải trình thanh tra BHXH

Đăng ký kênh nhé cả nhà

SÁCH QUYẾT TOÁN THUẾ


Liên hệ: 090.6969.247

Top